讓 ChatGPT 幫你搞定 Google 表單統計，變身試算表公式高手！

作者：蘇素雲 Celia Su - 9月 17, 2025

圖片來源：Canva AI 製作影像

之前寫了一篇如何用 ChatGPT 簡單讓 AI 幫我們自動辨識商家的 DM，解決常態性要幫同事訂飲料、便當的麻煩：

ChatGPT + Google Apps Script：快速自動化表單建立流程

有朋友問我：

但表單設計好了，不會寫試算表公式怎麼辦？
要統計早上的咖啡、中午的便當、下午的飲料，人數多，品項也多，好雜好亂，怎麼辦？

表單 AI 幫我們處理好了，後續透過 Google 試算表連動可以代公式做統計，簡單的公式加總，或許不需要 ChatGPT 幫忙，那如果你的表單要很貼心，有分類、品項很多，又想整合便當及早餐咖啡，得用較複雜的公式來協助，這時透過 ChatGPT，可以讓我們瞬間變身試算表高手。

用 ChatGPT 協助寫 Google 試算表公式，處理複雜的訂飲料與便當統計，第一次溝通除錯需要點時間，但做好後，以後就自由囉～解放你的時間與腦力。

公式說明

這次的示範內容是大茗本位的茶飲，因為它的 DM 分了六大類，茶品項目很多，為了有 DM 的人，方便看完再到表單上找品項，所以表單單選設計也分類了（主因是品項多）

因為分類了，所以表單送進來的內容，分在各欄中
簡單用的朋友，別分類，直接單選到底是最方便的

Google 表單回應資料示意，內容包含飲料名稱、分類、容量、甜度、冰量與數量統計等資訊

工作表 表單回應 1 是 Google 表單在回覆中點按 在試算表中查看，自動帶進來的
也因為分類，怕有人誤按一個以上，最後加個檢查欄位，只代簡單的公式
N2：=if(counta(C2:H2)=1,"",counta(C2:H2))，（往下複製公式）
若數量大於 1，問一下對方要加購還是誤按

Google 試算表統計飲料價格與配料加價的範例，公式使用 REGEX 擷取金額並自動加總

工作表 飲料統計 中的公式都是 ChatGPT 告知代進來的
A1 公式如下：（會自動往下代入）

=QUERY(

FLATTEN('表單回應 1'!C2:H),

"select Col1, count(Col1)

where Col1 is not null

group by Col1

order by count(Col1) desc",

)

當表單有寫入資料進來時，會自動代入品項及數量，遇到相同品項會自動加總，B 欄沒做任何動作
這是為了方便和店家核算數量和金額
單價因為有備註茶品特點，金額不是最後的數值，ChatGPT 給了公式
C2 公式：=IF(A2="","",VALUE(REGEXEXTRACT(A2,"\$(\d+)")))，往下複製公式

若要和店家訂飲料還是要用工作表 表單回應 1 中的內容，因為有包含沒有金額的甜度和冰塊多寡，加料選擇因為有價格，所以再列進工作表 飲料統計 中

F1 公式：
=TRANSPOSE( SORT( UNIQUE( FILTER('表單回應 1'!L2:L, '表單回應 1'!L2:L<>"") ) ) )
G1/H1 資料寫進來公式會自動帶，我們不做處理

數量統計公式：

=IF(OR($A2="",F$1=""),"",IFERROR(SUMPRODUCT((MMULT(--('表單回應 1'!$C$2:$H=$A2),TRANSPOSE(COLUMN('表單回應 1'!$C$1:$H$1)^0))>0)*('表單回應 1'!$L$2:$L=F$1)),0))
這部份要往左和往下複製公式
因為一堆 0 值不好判讀，有另加格式設定把 0 值隱藏

納入第二個表單

工作表 表單回應 2 是另一個 Google 表單，之所以拆開是因為飲料品項太多，且較常更換
7-11 飲料及便當品項相對少，且不常更動，所以二者同放在一個表單內
A1 公式：（會自動往下代入）

=QUERY('表單回應 2'!C2:C,

"select C, count(C)

where C is not null and C<>'' and C<>'不用,謝謝~'

group by C

order by count(C) desc

label C '咖啡項目', count(C) '數量'",

D1 公式：（會自動往下代入）

=QUERY('表單回應 2'!D2:D,

"select D, count(D)

where D is not null and D<>''

group by D

order by count(D) desc

label D '午餐品項', count(D) '數量'",

當表單有寫入資料進來時，會自動代入品項及數量，遇到相同品項會自動加總，B 欄及 E 欄沒做任何動作
F2 公式：=IF(D2="","",VALUE(REGEXEXTRACT(D2,"\$(\d+)")))，往下複製公式
G2 公式：=IF(D2="","",E2*F2)，往下複製公式
H1 公式：=SUM(G2:G)，總計金額

覆核內容

Google 試算表中統計未點選品項的複雜公式應用範例，含表單回應與邏輯判斷結果

因為有分區域，人數較多，若數量不夠，不知道誰沒點到，就無法個別通知，所以加了一個工作表，做為查核用

因為怕有人沒注意到分二張表單，已填表單的會自動代入
各品項都有點選了就打勾
比對所有與會人員名單，沒有登寫表單的就會在 全部未點 項下

查核公式

A 欄至 E 欄，欄名登入
A2 公式：（會自動往下代入）

=SORT(UNIQUE({
FILTER('表單回應 1'!B2:B, '表單回應 1'!B2:B<>"");
FILTER('表單回應 2'!B2:B, '表單回應 2'!B2:B<>"")
}))

B2 公式：（往下複製公式）

=IF($A2="","",

IF(

SUMPRODUCT(

('表單回應 1'!$B$2:$B=$A2)*

(MMULT(--('表單回應 1'!$C$2:$H<>""), TRANSPOSE(COLUMN('表單回應 1'!$C$1:$H$1)^0))>0)

)>0,

"✓","—"

)

C2 公式：（往下複製公式）

=IF($A2="","",

IF(COUNTIFS('表單回應 2'!$B$2:$B,$A2, '表單回應 2'!$C$2:$C,"<>")>0, "✓","—")

)

D2 公式：（往下複製公式）

=IF(A2="","",

IF(COUNTIFS('表單回應 2'!B$2:B,$A2,'表單回應 2'!D$2:D,"<>")>0,"✓","—"))

E2 公式：（會自動往下代入）

=IFERROR(

FILTER($G$2:$G,

ISNA(

MATCH(

$G$2:$G,

FILTER($A$2:$A, BYROW($B$2:$D, LAMBDA(r, COUNTIF(r,"✓")>0))),

)

"（皆已點）"

)

選用 LLM

看似有點複雜，也需要來回測試公式是否正確，有錯誤就和 ChatGPT 說，我們想要有什麼結果，也和它說，逐步修正到正確，就能留著當範本囉～

我是訂閱 ChatGPT Plus 版，有幾個較難的公式，它自己跑到 Thinking 模式，我個人是較喜歡 ChatGPT 5，就是因為它會自己判斷選用的模型，這才是最佳的，而不是還要我們自己依內容挑適合的模型，可以節省很多測試時間，雖然生圖功能 ChatGPT 4o，我個人覺得效果比較好。

一開始我有試圖先問過 Gemini，畢竟 Google 試算表和 Google 表單都是一條龍同公司的，但有可能是我用中文提問，我覺得它的中文理解能力略差於 ChatGPT，所以問第一個問題，它沒有回答的很好，我就改用 ChatGPT 了。

每款大語言模型，都有它的強弱項，多用一段時間，就能知道自己的工作或應用範圍，適合選擇哪款來用了。

雖然我還是提供了公式參考，但會建議自己試著提問，畢竟你的內容不會和我的一樣，且也不會只有一個要處理，對吧？

也因為點的便當和飲料不會一樣，若要分享試算表範本，也要自己弄表單，若有人有需求，留言區和我說，我再找時間，因為要忙著學校的課程，多點人有需求時，我再來處理。

友善提醒

有些小細節 ChatGPT 有可能給錯，能自己判讀的，自己修正就好，比如說：表單回應 2，它寫成了 表單回應2，多一個空格，就不一樣的
公式的邏輯是相同的，可以舉一反三套用，不一定內容都要和我的一樣
第一次套用，要多種可能自己測試一下，尤其是一下子太多資料進來，有可能就會有疏漏

搜尋此網誌

阿榮ㄟ厝Celia Su